pdfviewer — u_pbt_pdfviewer #

← Referencia de componentes · Índice de la guía

Visor de PDF integrado: muestra un documento local o publicado en la web, directamente dentro de su ventana, con paginación, zoom e impresión.

▶ Verlo en vivo — Aplicación de demostración, mosaico PDF viewer: la vista previa, el código que lo genera y esta página, uno al lado del otro.

De un vistazo #

El componente sustituye al clásico «guardar el PDF en un fichero temporal y después llamar a ShellExecute»: el documento permanece dentro de su aplicación y el usuario nunca abandona la pantalla en curso.

Inicio rápido #

// event open de la ventana : mostrar un documento presente en el disco
uo_pdf.is_source = "C:\factures\FA-2026-0142.pdf"

// event ue_load_completed de uo_pdf : (string as_source)
uo_status.of_panel(/*key*/ "main").is_text = "Documento mostrado"

Eso es todo: basta con asignar is_source para cargar y mostrar el documento.

Propiedades #

Métodos #

Eventos #

Por qué no se muestra un documento #

as_reason de ue_load_failed es una de estas constantes de u_pbt_pdfviewer. Un PDF se reconoce así: un fichero local tiene la extensión .pdf y empieza por la firma %PDF-; un documento remoto se sirve con el tipo application/pdf (el único que el motor entrega a su lector); una dirección data: anuncia application/pdf.

Lo que el usuario puede hacer, sin una sola línea de código #

El visor muestra su barra de herramientas integrada encima del documento. Usted no tiene que programar nada: la proporciona y la traduce el sistema.

Los atajos del navegador — Ctrl+F, Ctrl+P, Ctrl + rueda — están desactivados en todos los componentes, este incluido: use los botones de la barra del lector.

Lo que el lector no dice #

El lector es el integrado en el motor web: nada que instalar, impresión, búsqueda y formularios PDF incluidos. A cambio, no informa de nada a su aplicación: ni la página mostrada, ni el número de páginas, ni el zoom real, ni el texto seleccionado, y la búsqueda no se dirige desde el código: el lector ignora los parámetros de apertura que resaltarían un texto o abrirían su panel lateral. No tiene comando Pantalla completa y sigue el tema claro u oscuro de la aplicación, nunca el del componente. ii_page e ii_zoom dicen dónde abrir el documento, no dónde está el usuario. Un PDF protegido por contraseña: el lector la pide él mismo al usuario, su aplicación no puede proporcionarla. Es una elección deliberada; un renderizado programable requeriría una biblioteca externa.

Ejemplos #

Abrir un documento local #

// Ruta absoluta, o relativa al directorio de la aplicacion
uo_pdf.is_source = "doc\conditions-generales.pdf"

Abrir un documento publicado en la web #

// Una direccion web se carga exactamente como un fichero local
uo_pdf.is_source = "https://www.monsite.fr/tarifs/catalogue-2026.pdf"

Evidentemente se necesita una conexión a internet; la carga es asíncrona y ue_load_completed le indica el final.

Mostrar el PDF que acaba de producir una DataWindow #

// Local variables
string ls_file

// Un fichero por dia, en la carpeta temporal
ls_file = "C:\temp\report_" + String(Today(), "yyyymmdd") + ".pdf"

// La DataWindow produce el fichero...
dw_report.SaveAs(ls_file, PDF!, false)

// ...y el visor lo muestra inmediatamente
uo_pdf.is_source = ls_file

Actualizar después de regenerar el fichero #

// El fichero se ha reescrito en la misma ubicacion : recargar sin modificar is_source
uo_pdf.of_refresh()

Encadenar varios documentos en el mismo visor #

// event rowfocuschanged de dw_list : (long currentrow)
// Local variables
string ls_pdf

// La ruta del PDF de la fila actual
ls_pdf = dw_list.GetItemString(currentrow, "pdf_path")

// Sin adjunto el visor se vacia (conserva sus ajustes) ; si no, lo muestra
if ls_pdf = "" then
	uo_pdf.is_source = ""
else
	uo_pdf.is_source = ls_pdf
end if

Seguir el final de la carga #

// event ue_load_completed de uo_pdf : (string as_source)
uo_wait.Hide()

// of_print imprime el documento mostrado
uo_print_button.ib_enabled = true

Decir por qué el documento no está #

// event ue_load_failed de uo_pdf : (string as_source, string as_reason)
uo_wait.Hide()
choose case as_reason
	case uo_pdf.REASON_NOT_FOUND
		uo_status.of_panel(/*key*/ "main").is_text = "Documento no encontrado: " + as_source
	case uo_pdf.REASON_NOT_PDF
		uo_status.of_panel(/*key*/ "main").is_text = "Este fichero no es un PDF"
	case else
		uo_status.of_panel(/*key*/ "main").is_text = "Documento no disponible (" + as_reason + ")"
end choose

Abrir en otro sitio un enlace del documento #

// event ue_link_clicked de uo_pdf : (string as_url)
// El visor permanece en el documento : el enlace se abre en el navegador de la ventana
uo_web.is_address = as_url

Imprimir el documento #

// clicked del boton Imprimir : la vista previa del lector PDF, sobre el propio documento
if uo_pdf.of_print() = -4 then
	uo_status.of_panel(/*key*/ "main").is_text = "Ningun documento que imprimir"
end if

Mostrar sin dejar guardar ni imprimir #

// Un documento confidencial : ni Guardar ni Imprimir en la barra del lector
uo_pdf.ib_allow_save = false
uo_pdf.ib_allow_print = false
uo_pdf.is_source = is_current_document

Asígnelos antes de is_source: el documento se carga una sola vez. Cada visor conserva su propio ajuste. No es una protección: el fichero sigue siendo legible en el disco, y of_print sigue imprimiendo.

Vista previa en una pestaña, junto a la entrada de datos #

// event open : el visor ocupa una pagina de pestana, la entrada de datos la otra
uo_tab.of_add_page(/*key*/ "entry",  /*title*/ "Entrada",   /*page*/ uo_page_entry)
uo_tab.of_add_page(/*key*/ "preview",  /*title*/ "Vista previa",   /*page*/ uo_page_preview)

// El visor se coloca en uo_page_preview como cualquier otro control
uo_pdf.is_source = is_current_document

El componente se aloja sin ninguna precaución especial dentro de un tab o de un panel dockcontainer.

Comprobar el fichero antes de mostrarlo #

// Local variables
string ls_path

// El fichero de la factura mostrada
ls_path = "C:\factures\" + is_number + ".pdf"

// Sin fichero, nada que mostrar : vaciamos el visor en lugar de dejar el documento anterior
if not FileExists(ls_path) then
    uo_pdf.is_source = ""
    uo_status.of_panel(/*key*/ "main").is_text = "Factura no encontrada"
    return
end if

// Si no, se muestra la factura
uo_pdf.is_source = ls_path

Mostrar un PDF leído de la base de datos (blob) #

// Local variables
blob lblb_pdf

// La factura guardada en la base de datos, leida en un blob
SELECTBLOB pdf_file INTO :lblb_pdf FROM invoice WHERE invoice_no = :is_number USING SQLCA;

// Mostrada directamente desde la memoria : ningun fichero temporal, sea cual sea su tamano
if SQLCA.SQLCode = 0 then
	uo_pdf.of_load_blob(/*pdf*/ lblb_pdf, /*name*/ "invoice-" + is_number + ".pdf")
end if

El nombre dado vuelve en is_source y en ue_load_completed; el blob se libera con el documento siguiente o con of_reset.

Abrir en un capítulo #

// Abierto en el capitulo "prices" del catalogo; el boton Tabla de contenido del lector lista los marcadores
uo_pdf.is_destination = "prices"
uo_pdf.is_source = "doc\catalogue-2026.pdf"

El nombre de un destino es el que escribió la herramienta que generó el PDF: su generador de documentos lo conoce.

Un documento detrás de un token, o servido como octet-stream #

// Local variables
long ll_status
string ls_file

// El restclient (inv_rest, preparado al abrir la ventana) envia el token y descarga el fichero
ls_file = "C:\temp\invoice-4152.pdf"
ll_status = inv_rest.of_download(/*url*/ "/orders/4152/invoice.pdf", /*path*/ ls_file)

// Luego el visor muestra el fichero, sea cual sea el tipo anunciado por el servidor
if ll_status = 200 then
	uo_pdf.is_source = ls_file
end if

El lector del motor no sabe enviar un token ni mostrar una respuesta application/octet-stream (REASON_AUTH, REASON_NOT_PDF): el restclient lo hace por él.

Formatos y rutas admitidos #

Este componente solo admite PDF: lo demás se rechaza y se señala con ue_load_failed (REASON_NOT_PDF). Para una imagen, utilice picture; para una página HTML, webbrowser.

Buenas prácticas #

• Vigile ue_load_failed: una ruta no válida, un fichero que no es un PDF o un sitio inaccesible se señala ahí con su causa, y el visor permanece vacío.
• Para vaciar el visor (cambio de fila sin adjunto), asigne is_source = "": de lo contrario, el documento anterior permanece visible. of_reset() también lo vacía, pero además devuelve todos los ajustes a su valor por defecto — Guardar e Imprimir incluidos.
• of_refresh() es el modo de mostrar un fichero regenerado en la misma ruta: vuelve a leer el fichero sin tocar los ajustes. No conserva la posición de desplazamiento — el lector vuelve a empezar en ii_page.
• Cada cambio de ii_zoom, is_fit, ib_viewer_toolbar, is_destination, ib_allow_save o ib_allow_print vuelve a cargar el documento (el lector solo lee sus ajustes al cargar) y activa de nuevo ue_load_completed: asígnelos antes de is_source para una sola carga. El mismo valor asignado otra vez no vuelve a cargar nada. ii_page asignado mientras se muestra un documento vale para ese documento: para abrir otro en una página, asigne is_source y luego ii_page.
• Prevea un indicador de espera para los documentos remotos o voluminosos, y ocúltelo en ue_load_completed y en ue_load_failed.
• Dé al componente una superficie cómoda (al menos la mitad de la ventana): la barra de herramientas integrada y el documento necesitan espacio para seguir siendo legibles.
• Para mostrar una página web en lugar de un PDF, utilice webbrowser; para una imagen, picture.

Heredado de la base común #

Estos miembros existen en todos los componentes visuales — no son propios de este. Se detallan una sola vez, en los capítulos transversales; esta tabla solo dice dónde leerlos.

Dos ayudas no se heredan: of_icon y of_escape_markup viven en n_pbt_utils. Declare uno — n_pbt_utils lnv_utils, nada que crear — y llámelas sobre él.

← Referencia de componentes · Índice de la guía